This can be done with help of Mathematica as follows.
Let us exhaust the plane by disks centered at the origin. Switching to the polar coordinates, one obtains

 Integrate[r*Exp[a*x^2 + b*x*y + c*y^2] /. {x -> r*Cos[\[Phi]],y -> r*Sin[\[Phi]]}, {r, 0, R}]

> `(-1 + E^(R^2 (a Cos[\[Phi]]^2 + b Cos[\[Phi]] Sin[\[Phi]] + 
 c Sin[\[Phi]]^2)))/(a + c + (a - c) Cos[2 \[Phi]] + 
 b Sin[2 \[Phi]])`

It is clear the finite limit of the function defined by the above expression as `R->Infinity` exists only if `ForAll[\[Phi], \[Phi] > -Pi && \[Phi] <= Pi, 
 a Cos[\[Phi]]^2 + b Cos[\[Phi]] Sin[\[Phi]] + c Sin[\[Phi]]^2 < 0]` is valid as the result of

 Integrate[r*Exp[a*x^2 + b*x*y + c*y^2] /. {x -> r*Cos[\[Phi]], y -> r*Sin[\[Phi]]},
 {r, 0,Infinity},Assumptions -> {a, b, c} \[Element] Reals && \[Phi] > -Pi && \[Phi] <= Pi]

> `ConditionalExpression[-(1/(
 2 (a Cos[\[Phi]]^2 + b Cos[\[Phi]] Sin[\[Phi]] + c Sin[\[Phi]]^2))),
 a Cos[\[Phi]]^2 + b Cos[\[Phi]] Sin[\[Phi]] + c Sin[\[Phi]]^2 < 0]`

demonstrates.

 Unfortunately, Mathematica fails with

 Resolve[ForAll[\[Phi], \[Phi] > -Pi && \[Phi] <= Pi, 
 a Cos[\[Phi]]^2 + b Cos[\[Phi]] Sin[\[Phi]] + c Sin[\[Phi]]^2 < 0], Reals]
, returning the input. However, Mathematica is able to derive the condition in such a way

 Resolve[ForAll[y, y >= -1 && y <= 1,a y^2 + b *y*Sqrt[1 - y^2] + c (1 - y^2) < 0], Reals]

> `c < 0 && a < b^2/(4 c)`

Now

 Integrate[(-1)/(a + c + (a - c) Cos[2 \[Phi]] + b Sin[2 \[Phi]]), {\[Phi], -Pi, Pi}, 
 Assumptions -> c < 0 && a < b^2/(4 c) && a < 0 && b \[Element] Reals]

results in

> `ConditionalExpression[
 -Piecewise[{{0, (Sqrt[Abs[-(a/(a - I*b - c)) - c/(a - I*b - c) - Sqrt[-b^2 + 4*a*c]/(a - I*b - c)]] < 1 && 
 Sqrt[Abs[-(a/(a - I*b - c)) - c/(a - I*b - c) + Sqrt[-b^2 + 4*a*c]/(a - I*b - c)]] < 1) || 
 (Sqrt[Abs[-(a/(a - I*b - c)) - c/(a - I*b - c) - Sqrt[-b^2 + 4*a*c]/(a - I*b - c)]] >= 1 && 
 Sqrt[Abs[-(a/(a - I*b - c)) - c/(a - I*b - c) + Sqrt[-b^2 + 4*a*c]/(a - I*b - c)]] >= 1)}, 
 {(2*Pi)/Sqrt[-b^2 + 4*a*c], Sqrt[Abs[-(a/(a - I*b - c)) - c/(a - I*b - c) + Sqrt[-b^2 + 4*a*c]/(a - I*b - c)]] < 
 1}}, (-2*Pi)/Sqrt[-b^2 + 4*a*c]], 
 !(Sqrt[Abs[-(a/(a - I*b - c)) - c/(a - I*b - c) - Sqrt[-b^2 + 4*a*c]/(a - I*b - c)]] >= 1 && 
 Sqrt[Abs[-(a/(a - I*b - c)) - c/(a - I*b - c) - Sqrt[-b^2 + 4*a*c]/(a - I*b - c)]] <= 1) && 
 !(Sqrt[Abs[-(a/(a - I*b - c)) - c/(a - I*b - c) + Sqrt[-b^2 + 4*a*c]/(a - I*b - c)]] >= 1 && 
 Sqrt[Abs[-(a/(a - I*b - c)) - c/(a - I*b - c) + Sqrt[-b^2 + 4*a*c]/(a - I*b - c)]] <= 1)]`

, thinking a few hours. In fact, this is $$\frac{2 \pi }{\sqrt{4 a c-b^2}} $$ as `Simplify` under the conditions ` c < 0 && a < b^2/(4 c) && a < 0 && b \[Element] Reals]
` shows.