This answer does not produce very pretty outcomes, but it does correspond to the question request:

> I was wondering if there is a way to apply a continuous deformation to
> the data to get the final sphere (like blowing a balloon).

One thing this solution is good for -- i.e. more useful than the other solutions :) -- is to derive [autostereograms](https://en.wikipedia.org/wiki/Autostereogram). See the last section.

## Cow points

Generate random cow points:

 region = DiscretizeGraphics@ExampleData[{"Geometry3D", "Cow"}];
 cowPoints = RandomPoint[region, 6000];
 ListPointPlot3D[cowPoints, BoxRatios -> Automatic]

[![enter image description here][1]][1]

## Blowing up the cow (points)

Using this function:

 Clear[BlowUp]
 BlowUp[points_, center_, sfunc_] :=
 Map[sfunc[Abs[# - center]] (# - center) + center &, points]

and the *continuous function*:

 Plot[Evaluate@
 With[{a = 0.11}, 
 Piecewise[{{#, # < a}, {a Exp[2 (a - #)], # >= a}}] &][x], 
 {x, 0, 0.6}, PlotRange -> All]

[![enter image description here][2]][2]

we can blow up the cow points to get something close to a sphere:

 sphCowPoints = 
 BlowUp[cowPoints, Median[cowPoints], 
 With[{a = 0.11, k = 2}, {1, 1.8, 2} 
 Piecewise[{{k Norm[#], Norm[#] < a}, 
 {k a Exp[2 (a - Norm[#])], Norm[#] >= a}}] &]];
 ListPointPlot3D[sphCowPoints, BoxRatios -> Automatic]

[![enter image description here][3]][3]

## Magic eye spherical cows

Since [Yves Klet mentioned](http://mathematica.stackexchange.com/a/125145/34008) the WTC-2012 one-liners competition and one of my entries was an [autostereogram one-liner](https://antonantonov.wordpress.com/2012/10/23/wtc-2012-one-liner-first-entry/) here is code that generates a simple spherical cows autostereogram:

 rmat = N@RotationMatrix[-\[Pi]/4, {0, 0, 1}];
 tVec = {0.1, 0, 0};
 sirdPoints = NestList[Map[# + tVec &, #] &, sphCowPoints.rmat, 5];
 Graphics3D[{PointSize[0.002], 
 MapThread[{GrayLevel[0.8 - #2], Point[#1]} &, {Flatten[sirdPoints, 
 1], 0.8 Rescale[Flatten[sirdPoints, 1][[All, 2]]]}](*,Lighter[
 Blue],fence*)}, ViewPoint -> Front, Boxed -> False, 
 ImageSize -> 1200]

[![enter image description here][4]][4]


 [1]: https://i.sstatic.net/h2DA7.png
 [2]: https://i.sstatic.net/Q8tMqm.png
 [3]: https://i.sstatic.net/SAg9O.png
 [4]: https://i.sstatic.net/UsvAo.png