Solving third order ODE with DSolve

The equation in question does not seem to be solvable by DSolve. However, it can be tricked by substituting $y=z^n$, which results in an equation that is again not solvable by DSolve, but whose solution can be trivially found for certain values of $n$. Defining the left-hand side

lhs = y''[t]/y[t] + (9 y''[t]^2 - 6 y'[t] y'''[t])/y'[t]^2; 

and substituting

subst = y -> (#^n &)@*z; 

as suggested above, we get the left-hand side in terms of $z$:

lhsn = lhs /. subst // Simplify (* (-3-n+4n^2)z'[t]^2/z[t]^2 + n z''[t]/z[t]+(9z''[t]^2-6z'[t]z'''[t])/z'[t]^2 *) 

The quadratic polynomial in the numerator of the first fraction has two real solutions:

{sol1, sol2} = Solve[lhsn[[1, 1]] == 0, n] (* {{n -> -(3/4)}, {n -> 1}} *) 

In the case of $n=-3/4$ the only difference is that the fraction $z''[t]/z[t]$ gets the factor $-3/4$ compared to the original l.h.s. Taking a common denominator and setting the numerator equal to zero gives the l.h.s. of a new equation:

lhsn /. sol1 lhs1 = % // Together // Numerator // Last (* -3z''[t]/(4z[t]) + (9z''[t]^2 - 6z'[t]z'''[t])/z'[t]^2 *) (* -z'[t]^2 z''[t] + 12z[t]z''[t]^2 - 8z[t]z'[t]z'''[t] *) 

Although this new equation is also not solvable by DSolve, it obviously has a linear solution

zlin = a + b # &; lhs1 == 0 /. z -> zlin (* True *) 

All that remains is to find the coefficients $a,b$ from the given initial conditions:

Through[({y, y'} /. subst /. sol1 /. z -> zlin)[t]] First@Solve[(% /. t -> 0) == {1, 1}, {a, b}] zlin /. %; y1 = y /. subst /. sol1 /. z -> %; y1[t] lhs == 0 /.y->y1(* verify that y1 is a solution of the original equation *) (* {1/(a + b t)^(3/4), -((3 b)/(4 (a + b t)^(7/4)))} *) (* {a -> 1, b -> -(4/3)} *) (* 1/(1 - (4 t)/3)^(3/4) *) (* True *) 

In the case of $n=1$, of course, the left side is invariant. The rest of the procedure is similar:

lhsn /. sol2 lhs2 = % // Together // Numerator (%% /. z -> y) === lhs (* z''[t]/z[t] + (9z''[t]^2 - 6z'[t]z'''[t])/z'[t]^2 *) (* z'[t]^2 z''[t] + 9z[t]z''[t]^2 - 6z[t]z'[t]z'''[t] *) (* True *) 

Again, although this new equation is not solvable by DSolve, the same linear function is a solution:

lhs2 == 0 /. z -> zlin (* True *) 

Finding the coefficients $a,b$ from the initial conditions gives:

Through[({y, y'} /. subst /. sol2 /. z -> zlin)[t]] First@Solve[(% /. t -> 0) == {1, 1}, {a, b}] zlin /. %; y2 = y /. subst /. sol2 /. z -> %; y2[t] lhs == 0 /. y -> y2(* verify that y2 is a solution of the original equation *) (* {a + b t, b} *) (* {a -> 1, b -> 1} *) (* 1 + t *) (* True *) 

Summary: The solutions found by Maple are easy to reproduce. But are there other, less trivial solutions for general values of $n$?

UPDATE

I tried to graphically illustrate the behavior of the yarchik's general solution with the specified initial conditions (given in terms of the hypergeometric function ${}_2F_1$), so that only one integration constant $c_1$ remains, and its relationship to both limit solutions.

For $c_1\to \pm\infty$ the general solution converges to the linear solution $y=1+t$, and the WL is able compute these limits although it takes about 2 minutes on my computer.

For $c_1\to 0_{-}$, it appears that the general solution converges to the $y=(1-4t/3)^{-3/4}$ solution (as shown by yarchik), which appears to be true also for $c_1\to 0_{+}$. However, the WL is not able to evaluate these limits, it simply gives up after 5 minutes or so.

When further increasing $c_1$ from $0$ and approaching the critical value $3/7\approx 0.428571$ from below, the general solution appears to be converging to zero (dotted black 'right-angled' line labeled as $3/7_{-}$ in the picture) on the interval $y\in(1,\infty)$. When $c_1$ crosses $3/7$, the general solution suddenly flips over and becomes close to zero for $y\in(0,1)$ (dash-dotted black 'right-angled' line labeled as $3/7_{+}$ in the picture). Both one-sided limits are evaluatable by the WL as $0$, but it takes a long time.

Finally, when increasing $c_1$ from $3/7$ to $+\infty$, the general solution approaches the linear solution $y=1+t$ from above again.

Some parts of the behavior are my guesses based only on the pictorial view, not supported by exact computation of limits, namely in the case $c_1\to 0_\pm$, when the WL fails. I am also unsure how to correctly express the closeness to the 'right-angled' lines, apologies for that.

The overall picture illustrating the behavior is here (the small bold numbers are the $c_1$ values):

UPDATE 2

Using the formula $$[(y')^{-3/2}y'']' = (-1/6)(y')^{-5/2}[9(y'')^2 - 6y' y'''],$$ the following first integral can be obtained: $$y^{1/6} = \frac{\sqrt{c_ 2}}{7} (y')^{-3/2} y''$$ Here I deliberately chose the integration constant $c_2$ to match $c_2$ in yarchik's solution. This can be further integrated using the formula $$[(y')^{-1/2}]' = (-1/2)(y')^{-3/2}y''$$ which results in $$\frac{c_ 2}{49} y' = \left(\frac{3}{7}y^{7/6} - c_ 1\right)^{\!2}$$ (with $c_1$ appropriately selected). The problem is now reduced to a simple quadrature: $$x = \frac{c_2}{49 c_1^2} \int \left( 1-\frac{3y^{7/6}}{7c_1} \right)^{\!\!-2}\,dy + c_3$$ Pasting this into WL code gives yarchik's solution in terms of ${}_2F_1$:

(C[2]/(49 C[1]^2)) Integrate[(1 - 3 y^(7/6)/(7 C[1]))^-2, y] 

$$x = \frac{c_2 y}{49c_1^2} {}_ 2\!\,F_1(\frac{6}{7},2;\frac{13}{7};\frac{3y^{7/6}}{7c_1}) + c_3$$

However, I have to admit that I did all the transformations leading to the quadrature manually, without the help of the WL, which only did the last step. The reason is that I could not satisfactorily perform these algebraic and differential transformations using standard WL functions such as Collect, Apart, Together, Cancel, D, ReplaceAll, Numerator, Denominator, Simplify, etc. In my opinion, it is faster to derive all the transformations manually than to develop complex single-purpose code for a particular case. Is it just my inability to write such code, or is WL really difficult to perform such a task? Is there any advice on how to perform this task effectively?