3
$\begingroup$

The LiouvilleLambda function has Dirichlet generating function of Zeta[2s]/Zeta[s]. I am curious about an analogous function with Dirichlet generating function of Zeta[3s]/Zeta[s].

Can Mathematica return the first few terms of such a sequence?

I am most interested in a code that is simple to understand. I am not concerned about efficiency.

Improve this question
$\endgroup$
1
  • $\begingroup$ The PARI program is better for the expansion of Dirichlet g.f.: for(n=1, 100, print1(direuler(p=2, n, (1 - X)/(1 - X^3))[n], ", ")). $\endgroup$ Commented Jul 3, 2020 at 7:57

1 Answer 1

Reset to default
3
$\begingroup$

(See EDIT #3 below for an explicit formula, and EDIT #2 for a solution comparing Dirichlet coefficients)

Answer

19.03.15 20:20

We can get the first few terms in Mathematica in a straighforward manner as follows.

Let

z[s_]:=Zeta[3s]/Zeta[s] t[s_,m_]:= Sum[f[n]/n^s,{n,1,m}]

Then we have

z[s] = f[1] + f[2]/2^s + f[3]/3^s + ...

Hence 

f[1] = Limit[z[s], s -> \[Infinity]] (* Out[35]= 1 *) f[2] = Limit[2^s (z[s] - 1), s -> \[Infinity]] (* Out[5]= -1 *) f[3] = Limit[3^s (z[s] - t[s, 2]), s -> \[Infinity]] (* Out[9]= 0 *)

Continuing this procedure in Mathematica leads to f[3] = f[4] = ... = 0. But this is obviously wrong.

We can see what's happening here by plotting the functions

g[3] = 3^s (z[s] - t[s, 2]) g[4] = 4^s (z[s] - t[s, 3]) g[n_]:=n^s (z[s] - t[s,n-1])

in the range from s = 0 to s ~= 25. Starting from n = 4 we see strong oscillations due to inaccuracy but we can still guess the true result of the limit up to n = 10.

Here are some typical plots

enter image description here enter image description here enter image description here enter image description here enter image description here

This way I came up with the sequence

f = {1, -1, -1, 0, -1, 1, -1, 1, 0, 1}

After n = 10 the accuracy decreases drastically, and I stopped.

Then I looked up the OEIS database, and I found several entries. The most interesting is A210826.

Here we find the comment:

Conjecture: this is a multiplicative sequence with Dirichlet g.f. zeta(3s)/zeta(s)

And - believe it or not, dear Geoffrey - your own MATHEMATICA entry as of TODAY:

Mod[Table[DivisorSigma[0, n], {n, 1, 100}], 3, -1] (* Geoffrey Critzer, Mar 19 2015 *)

Very nice, but I would greatly appreciate to see your proof.

EDIT #1

The procedure does not give reasonable results for Zeta[4s]/Zeta[s]. I don't know if this is a question of accuracy already for n=4 or if Zeta[4s]/Zeta[s] can be written in the form of t[s] at all.

EDIT #2

24.03.15

Solution by direct computation, i.e. comparing "Dirichlet"-powers n^-x of the two expressions Zeta[k*x] and Zeta[x] * Sum[f[n]/n^x,{n,1,oo}]

fqZeta[k_, nn_] := Module[{z, d, x, g, eqs, sol, t}, z[x_, p_] := Sum[1/n^x, {n, 1, p}]; d[x_, p_] := Sum[f[n]/n^x, {n, 1, p}]; g[k] = (z[k x, nn] - z[x, nn]*d[x, nn] // Expand) /. a_^( c_ b_) -> Simplify[(a^b)]^c; eqs[k] = Table[0 == (1/m^-x Plus @@ Cases[g[k], _. m^-x]) // Simplify, {m, 2, nn}]; sol[k] = Solve[Join[{f[1] == 1}, eqs[k]]][[1]]; t[k] = Table[f[n], {n, 1, nn}] /. sol[k]]

Example

fqZeta[4, 25] (* Out[385]= {1, -1, -1, 0, -1, 1, -1, 0, 0, 1, -1, 0, -1, 1, 1, 1, -1, \ 0, -1, 0, 1, 1, -1, 0, 0} *)

No specific problems for large k found. Here's k = 9:

dt89 = Timing[fqZeta[9, 400] - fqZeta[8, 400]]; dt89[[1]] (* Out[370]= 73.663 *)

Fairly quick and

Select[dt89[[2]], # != 0 &] (* Out[371]= {-1} *)

different from k = 8 at

Position[dt89[[2]], -1] (* {{256}} *)

EDIT #3: Explicit formula

28.03.15

The formula

We give an explicit formula for the Dirichlet coefficient $\text{a(k,n)}$ of $\text{$\zeta $(k x)/$\zeta $(x)}$ for integer $k>0$.

The defining identity for $a(n)$ is

$$\text{$\zeta $(k x)/$\zeta $(x) = Sum$\_\{$n$>$=1$\}$ a(k,n)/r${}^{\wedge}$x}$$

and we have

$$\text{a(k,n) = Sum$\_\{$d${}^{\wedge}$k$|$n$\}$ $\mu $(n/d${}^{\wedge}$k)}$$

where $\text{$\mu $(n)}$ is the Moebius function.

Proof

To prove the formula we need two ingredients

1) the Dirichlet series of 1/$\zeta $(x). Which is

$$\text{1/$\zeta $(x) = Sum$\_\{$n$>$=1$\}$ $\mu $(n)/n${}^{\wedge}$x}$$

2) the Dirichlet series of a product of two Dirichlet series

$$\text{(Sum$\_\{$n$>$=1$\}$ u(n)/n${}^{\wedge}$x)*(Sum$\_\{$m$>$=1$\}$ v(m)/m${}^{\wedge}$x) = Sum$\_\{$r$>$=1$\}$ w(r)/r${}^{\wedge}$x}$$

where $\text{w(r) = Sum$\_\{$d$|$r$\}$ u(d) v(r/d)}$

Both relations are standard number theory knowledge, and I'll leave it to the reader as a nice exercise to derive them by himself.

Mathematica

In Mathematica we can write the Dirichlet coefficient as

a[k_, n_] := Plus @@ (MoebiusMu[n/#^k] & /@ Select[(Divisors[n])^(1/k), IntegerQ[#] &])

Examples

Table[a[1, n], {n, 1, 10}] (* Out[390]= {1, 0, 0, 0, 0, 0, 0, 0, 0, 0} *) Table[a[2, n], {n, 1, 10}] (* Out[391]= {1, -1, -1, 1, -1, 1, -1, -1, 1, 1} *)

Note that $\text{a(2,n)}$ is the Liouville function $\text{$\lambda $(n)}$.

Table[Print[{k, Table[ToString[a[k, n]] /. {"0" -> " 0", "1" -> " 1"}, {n, 1, 32}]}], {k, 2, 6}]; {2,{ 1,-1,-1, 1,-1, 1,-1,-1, 1, 1,-1,-1,-1, 1, 1, 1,-1,-1,-1,-1, 1, 1,-1, 1, 1, 1,-1,-1,-1,-1,-1,-1}} {3,{ 1,-1,-1, 0,-1, 1,-1, 1, 0, 1,-1, 0,-1, 1, 1,-1,-1, 0,-1, 0, 1, 1,-1,-1, 0, 1, 1, 0,-1,-1,-1, 0}} {4,{ 1,-1,-1, 0,-1, 1,-1, 0, 0, 1,-1, 0,-1, 1, 1, 1,-1, 0,-1, 0, 1, 1,-1, 0, 0, 1, 0, 0,-1,-1,-1,-1}} {5,{ 1,-1,-1, 0,-1, 1,-1, 0, 0, 1,-1, 0,-1, 1, 1, 0,-1, 0,-1, 0, 1, 1,-1, 0, 0, 1, 0, 0,-1,-1,-1, 1}} {6,{ 1,-1,-1, 0,-1, 1,-1, 0, 0, 1,-1, 0,-1, 1, 1, 0,-1, 0,-1, 0, 1, 1,-1, 0, 0, 1, 0, 0,-1,-1,-1, 0}}

Remarks

1) For small k the series are in OEIS (https://oeis.org/)

k = 2
A008836
Liouville's function $\text{$\lambda $(n)} = (-1){}^{\wedge}$k, where k is number of primes dividing n (counted with multiplicity), N. J. A. Sloane

k = 3
A210826
G.f.: $\text{Sum$\_\{$n$>$=1$\}$ a(n)*x${}^{\wedge}$n/(1 - x${}^{\wedge}$n) = Sum$\_\{$n$>$=1$\}$ x${}^{\wedge}$(n${}^{\wedge}$3)}$, Paul D. Hanna, Mar 27 2012

k = 4
A219009
Coefficients of the Dirichlet series for zeta(4s)/zeta(s), Benoit Cloitre, Nov 09 2012

k = 5
A253206
Coefficients of the Dirichlet series for zeta(5x)/zeta(x), here the Mathematica formula for a[k,n] is given, Wolfgang Hintze, Mar 25 2015

2) Miscellaneous

a) Prove that $\text{a(k,n) $\in $ $\{$-1,0,1$\}$}$

Improve this answer
$\endgroup$
11
  • $\begingroup$ Lets look at OEIS A007425, the number of divisors of n's divisors. a(n) is congruent to 1 (mod 3) iff n is a cube, otherwise a(n) is congruent to 0 (mod 3). If we multiply the Dirichlet series Sum_{n>=1}A210826(n)/n^s * zeta(s) we will get the characteristic function for the perfect cubes, i.e. zeta(3*s). $\endgroup$ Commented Mar 20, 2015 at 16:42
  • $\begingroup$ Zeta[4s]/Zeta[s] in given in OEIS A219009 but I do not understand the code that is given nor the significance of the terms. $\endgroup$ Commented Mar 20, 2015 at 17:13
  • $\begingroup$ Thanks for your replies. (1) I have to study them in detail, as I am not an expert in number theory. (2) my general question was: is it possible to represent Zeta[n*s]/Zeta[s] for any integer n > 3 in the form of a Dirichlet series ? $\endgroup$ Commented Mar 20, 2015 at 18:10
  • $\begingroup$ (1) I checked by comparision of coefficients that OEIS A219009 is generated by the Lambert series for Sum[q^(n^4],{n,0,oo}] = Sum[a[n] q^n/(1-q^n),{n,1,oo}] (2) the same for Sum[q^(n^5],{n,0,oo}] which gives A008683 except for n=32 and n=64 (in the range up to n = 243) (3) I have not understood the relation of the Lambert series to the Zeta[k*s]/Zeta Business. $\endgroup$ Commented Mar 20, 2015 at 20:32
  • $\begingroup$ OK, thank you. I have not previously considered Lambert series but now I see how they can answer my original question. nn = 20; f[x_] := Sum[a[n] x^n/(1 - x^n), {n, 1, nn}]; SolveAlways[ 0 == Series[f[x] - Sum[x^(n^3), {n, 1, nn}], {x, 0, nn}], x] $\endgroup$ Commented Mar 20, 2015 at 22:37

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.