ClearAll[rectilinearPoly]
 rectilinearPoly = BoundaryDiscretizeGraphics @* ReplaceAll[Line -> Polygon]@* 
 (ListStepPlot[#, Right, PlotRange -> All] &);
 

***Examples:***

 SeedRandom[1]
 coords = #[[FindShortestTour[#][[2]]]] & /@ RandomReal[{-1, 1}, {5, 6, 2}];

 Row[Show[rectilinearPoly@#, Graphics[{Red, PointSize[Medium], Point@#}], 
 ImageSize -> 1 -> 100] & /@ coords, Spacer[10]]

[![enter image description here][1]][1]

 ClearAll[highLight]
 highLight[col_: LightBlue] := HighlightMesh[#, Style[2, Opacity[.5, col]]] &;

 Row[Show[highLight[RandomColor[]] @ rectilinearPoly@#, 
 Graphics[{Red, PointSize[Medium], Point@#}], ImageSize -> 1 -> 100] & /@ coords, 
 Spacer[10]]

[![enter image description here][2]][2]


 SeedRandom[1]
 coords2 = Append[#, First@#] & /@ RandomReal[{-1, 1}, {5, 6, 2}];
 Row[Show[highLight[RandomColor[]]@rectilinearPoly@#, 
 Graphics[{Red, PointSize[Medium], Point@#}], 
 ImageSize -> 1 -> 100] & /@ coords2, Spacer[10]]

[![enter image description here][3]][3]


 [1]: https://i.sstatic.net/DiiVy.png
 [2]: https://i.sstatic.net/LcfHd.png
 [3]: https://i.sstatic.net/Dt8Z1.png