[`NextPrime`](https://reference.wolfram.com/language/ref/NextPrime.html) has no problems evaluating for large numbers well above $10^{14}$. I think it's safe to assume these are real prime numbers, for confirmation see the answer by @Roman (+1).

You can benchmark the performance of or your analysis using [`AbsoluteTiming`](https://reference.wolfram.com/language/ref/AbsoluteTiming.html) or [`RepeatedTiming`](https://reference.wolfram.com/language/ref/RepeatedTiming.html) for better statistics.

 RepeatedTiming[
 NextPrime[
 RandomInteger[10^40]
 ]
 ,10
 ]

 (* {0.00116824, 7254438951606515242301428266213800581027} *)

So after evaluating random large numbers repeatedly for *10 second*s, we get an average of *1.117ms* per evaluation.

We expect that there will be approximately $n/Log(n)$ prime numbers smaller than $n$ ([Prime number theorem][1]), so assuming *1ms* per iteration, your calculation will take more than *98 years*.

 With[
 { n = 10^14 },
 UnitConvert[
 Quantity[1., "Millisecond"] * n/Log[n] 
 ,"Years"
 ]
 ]
 (* Quantity[98.36705486320665, "Years"] *)

So unless your machine is much faster than mine and you have access to several hundreds of cores, even speeding things up via compilation, I think it may be hard to go over all prime numbers in the range $2$ to $10^{14}$ and do any meaningful tests on them.

<hr>

### Edit

After the excellent comment by @GregHurst code like the one below from [here][2], could bring you down to a couple of weeks, without taking into account the time for your test. 

As pointed out by @Roman, there are `PrimePi[10^14]`$= 3204941750802$ prime numbers below $10^{14}$, and you better not try to have them all in memory (46 TB). 
 

 PrimesUpTo = Compile[{{n, _Integer}},
 Block[{S = Range[2, n]},
 Do[
 If[S[[i]] != 0,
 Do[
 S[[k]] = 0,
 {k, 2i+1, n-1, i+1}
 ]
 ],
 {i, Sqrt[n]}
 ];
 Select[S, Positive]
 ],
 CompilationTarget -> "C",
 RuntimeOptions -> "Speed"
 ];

[![enter image description here][3]][3]


 [1]: https://en.wikipedia.org/wiki/Prime_number_theorem
 [2]: https://mathematica.stackexchange.com/a/85720/10397
 [3]: https://i.sstatic.net/9QkTx.png