Selective list deletions

Question

I have a list:

lis = {{a,b,c},{d},{e,f},{g},{h,i,j}}

I would like to remove each element that consists of only one subelement from the list to get:

res = {{a,b,c},{e,f},{h,i,j}}

This seems to be for SequenceReplace, but I'm having trouble with structuring the command.

Syed · Accepted Answer · 2021-10-07 12:39:40Z

11

Cases[lis, Except[{_}]] should be good.

OR

Select[lis, Length[#] > 1 &] Pick[lis, Length[#] > 1 & /@ lis] DeleteCases[lis, {_}] lis /. {_} -> Nothing

EDIT a few more

Select[lis, Rest[#] != {} &] Select[lis, Most[#] != {} &] Select[lis, Last@TakeDrop[#, 1] != {} &]

answered Oct 6, 2021 at 18:27

62.9k5 gold badges48 silver badges103 bronze badges

kglr · Accepted Answer · 2021-10-06 18:46:10Z

10

Cases[{_, __}] @ lis

{{a, b, c}, {e, f}, {h, i, j}}

answered Oct 6, 2021 at 18:46

403k18 gold badges501 silver badges959 bronze badges

eldo · Accepted Answer · 2024-03-13 00:08:31Z

list = {{a, b, c}, {d}, {e, f}, {g}, {h, i, j}};

Using SequenceSplit (new in 11.3)

Catenate @ SequenceSplit[list, {{_}}]

{{a, b, c}, {e, f}, {h, i, j}}

E. Chan-López · Accepted Answer · 2024-03-13 00:16:44Z

4

list = {{a, b, c}, {d}, {e, f}, {g}, {h, i, j}};

Using GroupBy:

GroupBy[list, Length@# > 1 &][True] (*{{a, b, c}, {e, f}, {h, i, j}}*)

Or using Replace at level 1:

Replace[list, s : {_} :> Nothing, {1}] (*{{a, b, c}, {e, f}, {h, i, j}}*)

answered Mar 13, 2024 at 0:16

33.7k3 gold badges34 silver badges54 bronze badges

4 Answers 4