5
$\begingroup$

I am trying to find a general expression for x, for the following equation y = 5 + 2 x + x^a, but Solve cannot accomplish this.

I am using Solve[{y == 5 + 2 x + x^a}, {x}]

If I put any numerical for a, for example a = 0.5, it works and it gives me the roots, but it doesn't give me a general expression for any a.

a is between 0 and 1, i.e 0 < a < 1.

How can I get a general expression for x as a function of y and a?

Improve this question
$\endgroup$
3
  • 3
    $\begingroup$ For general a mathematically is impossible to obtain a symbolic(analytic) solution, because there is a lack of tools in mathematics to solve this equation.Then Mathematica can't solve. $\endgroup$ Commented Jul 15, 2019 at 16:32
  • 3
    $\begingroup$ A symbolic solution is only possible for a rational $a$, it is then expressible in terms of the hypergeometric function. For an irrational $a$, a solution is only possible in terms of series. See here, mathoverflow.net/questions/249060/… $\endgroup$ Commented Jul 15, 2019 at 16:35
  • 1
    $\begingroup$ The irrational $a$ case @yarchik was talking about is expressible as a Fox $H$-function, which degenerates to a sum of Meijer $G$-functions (equivalently, a sum of hypergeometric functions) when $a$ is rational. Unfortunately Fox $H$ is not yet implemented in Mathematica. $\endgroup$ Commented Nov 17, 2019 at 22:42

1 Answer 1

Reset to default
10
$\begingroup$

Generic trinomial equation $w x^a-x+1=0$

A particular solution such that $x→1$ for $w→0$ is known in analytical form M.L.Glasser, J. Comp. Appl. Math. 118, 169 (2000)

f[a_,w_]:=1+Sum[w^n/n Binomial[a n,n-1],{n,1,∞}]

Example A.1 simple quadratic equation

α=2; x=f[α,w] Simplify[1-x+ w x^α] Out[1]= 1+(1-Sqrt[1-4 w]-2 w)/(2 w) Out[2]= 0

Example A.2 cubic equation

α=3; x=f[α,w] Simplify[1-x+ w x^α] Out[3]= 1+(-3 Sqrt[w]+2 Sqrt[3] Sin[1/3 ArcSin[(3 Sqrt[3] Sqrt[w])/2]])/(3 Sqrt[w]) Out[4]= 0

Trinomial equation of the type $x^α-p x+q=0$

Solution is obtained from a generic formula by simple rescaling

g[a_,p_,q_]:=(q/p) f[a,q^(a-1)/p^a]

Example B.1 general quadratic equation

Clear[α,p,q] p=-2; α=2; x=g[α,p,q] Simplify[x^α-p x+q] Out[5]= -(1/2) (1+(2-2 Sqrt[1-q]-q)/q) q Out[6]= 0

Example B.2 cubic equation

Clear[α,p,q] p=-2; α=3; x=g[α,p,q] Simplify[x^α-p x+q] Out[7]= -(1/2) q (1+(-3 q+4 Sqrt[6] Sinh[1/3 ArcSinh[3/4 Sqrt[3/2] q]])/(3 q)) Out[8]= 0

Example B.3 quintic

Clear[α,p,q] p=-2; α=5; x=g[α,p,q] Series[x^α-p x+q,{q,0,10}]//Normal Out[9]= -(1/2) q HypergeometricPFQ[{1/5,2/5,3/5,4/5},{1/2,3/4,5/4},-((3125 q^4)/8192)] Out[10]= 0

Example B.4 exponent $\frac52$

Clear[α,p,q] p=-2; α=5/2; x=g[α,p,q] N[x^α-p x+q/.q->-1] Out[11]= -(1/2) q (1+1/8 (-8+8 HypergeometricPFQ[{1/5,2/5,3/5,4/5},{1/2,2/3,4/3},-((3125 q^3)/3456)] -I Sqrt[2] q^(3/2) HypergeometricPFQ[{7/10,9/10,11/10,13/10},{7/6,3/2,11/6},-((3125 q^3)/3456)])) Out[12]= 8.32667*10^-17

Trinomial equations is an interesting piece of mathematics. The case of integer exponents is discussed in this post here, the case of arbitrary real exponents is discussed in this post on mathoverflow. They can be summarized as follows:

  1. Chip Hurst obtains solutions in terms of hypergeometric functions by expanding in series the Root object.
  2. J.M. arrives at another form in terms of MeijerG functions by generalizing the method in the Glasser's paper.
  3. Pietro Majer derives a series solution by using the inversion formula for the function $f(x)=x+ax^p+bx^q$ with real exponents $p>1$ and $q>1$.
Improve this answer
$\endgroup$
2
  • $\begingroup$ It seems I've seen this equation, or a similar one, on this site in years past. It would be nice to link it, if someone can find it, especially if it's equivalent. (I failed.) +1 $\endgroup$ Commented Jul 16, 2019 at 21:44
  • $\begingroup$ @MichaelE2 Thank you, the post is expanded now to show the connections. $\endgroup$ Commented Jul 17, 2019 at 8:05

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.