6
$\begingroup$

I have trouble simplifying the following matrix

A = {{(a^2 + b^2 + c^2 + Im[Sqrt[(a - I*b)^2 + c^2]]^2 + Re[Sqrt[(a - I*b)^2 + c^2]]^2)/ (2*Sqrt[(a - I*b)^2 + c^2]*Conjugate[ Sqrt[(a - I*b)^2 + c^2]]), (I*b*c)/(Sqrt[(a - I*b)^2 + c^2]*Conjugate[ Sqrt[(a - I*b)^2 + c^2]])}, {(-((a + I*b)*(a^2 + b^2 + c^2)) + (a - I*b)*Conjugate[Sqrt[(a - I*b)^2 + c^2]]^2)/ (2*c*Sqrt[(a - I*b)^2 + c^2]*Conjugate[ Sqrt[(a - I*b)^2 + c^2]]), (Sqrt[(a - I*b)^2 + c^2] + (2*b*((-I)*a + b))/ Conjugate[Sqrt[(a - I*b)^2 + c^2]] + Conjugate[Sqrt[(a - I*b)^2 + c^2]])/ (2*Sqrt[(a - I*b)^2 + c^2])}};

Here, $a,b,c$ are all real and positive. Firstly, Im[Sqrt[(a - I*b)^2 + c^2]]^2 + Re[Sqrt[(a - I*b)^2 + c^2]]^2 should be just Abs[Sqrt[(a - I*b)^2 + c^2]]^2. Secondly, when checked numerically, the diagonal elements seems to be identical. How can I simplify this matrix in the best possible way?

Improve this question
$\endgroup$
1
  • 1
    $\begingroup$ Try ComplexExpand. $\endgroup$ Commented May 12, 2024 at 18:02

2 Answers 2

Reset to default
2
$\begingroup$

I don't know if this helps, but

f[e_] := 100 Count[e, _Conjugate, {0, Infinity}] + 100 Count[e, _Sign, {0, Infinity}] + LeafCount[e]; FullSimplify[A, Assumptions -> {a > 0, b > 0, c > 0}, ComplexityFunction -> f]

yields

{{1/2 (1 + (a^2 + b^2 + c^2)/Abs[(a - I b)^2 + c^2]), (I b c)/ Abs[(a - I b)^2 + c^2]}, {-((I b c)/Abs[(a - I b)^2 + c^2]), ( 2 b (-I a + b) + Abs[(a - I b)^2 + c^2] + Conjugate[Sqrt[(a - I b)^2 + c^2]]^2)/(2 Abs[(a - I b)^2 + c^2])}}

which shows that the off-diagonal elements appear to be opposite sign.

Improve this answer
$\endgroup$
1
$\begingroup$

To simplify objects with complex numbers, we can use ComplexExpand first.

Assuming[a > 0 && b > 0 && c > 0, A // ComplexExpand // FullSimplify] (* {{(a^2 + b^2 + c^2 + Sqrt[4 a^2 b^2 + (a^2 - b^2 + c^2)^2])/( 2 Sqrt[4 a^2 b^2 + (a^2 - b^2 + c^2)^2]), (I b c)/Sqrt[ 4 a^2 b^2 + (a^2 - b^2 + c^2)^2]}, {-((I b c)/Sqrt[ 4 a^2 b^2 + (a^2 - b^2 + c^2)^2]), ( a^2 + b^2 + c^2 + Sqrt[4 a^2 b^2 + (a^2 - b^2 + c^2)^2])/( 2 Sqrt[4 a^2 b^2 + (a^2 - b^2 + c^2)^2])}}*)
Improve this answer
$\endgroup$

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.