How to remove the given columns and strings?

Question

Consider a data having the form

data={{P,4,3,2},{V,7,8,9,55},{P,19,3,4},{V,48,6,1,55}}

How to remove all rows with V and then to remove the first column, i.e., to get

dataprime={{4,3,2},{19,3,4}}

MelaGo · Accepted Answer · 2019-04-22 17:56:22Z

4

DeleteCases[data, {V, ___}][[All, 2 ;;]]

{{4, 3, 2}, {19, 3, 4}}

answered Apr 22, 2019 at 17:56

9,3811 gold badge12 silver badges26 bronze badges

eldo · Accepted Answer · 2024-02-06 00:13:10Z

data = {{P, 4, 3, 2}, {V, 7, 8, 9, 55}, {P, 19, 3, 4}, {V, 48, 6, 1, 55}};

Two other possibilities

Cases[data, {P, a__} :> {a}]

{{4, 3, 2}, {19, 3, 4}}

Rest @@@ SequenceSplit[data, {{V, __}}]

{{4, 3, 2}, {19, 3, 4}}

E. Chan-López · Accepted Answer · 2024-02-06 03:17:25Z

data = {{P, 4, 3, 2}, {V, 7, 8, 9, 55}, {P, 19, 3, 4}, {V, 48, 6, 1, 55}};

Using SequenceCases:

SequenceCases[data, {s : {P, __}} :> Rest@s] (*{4, 3, 2}, {19, 3, 4}}*)

Or using ReplaceList:

ReplaceList[data, {___, s : {P, __}, ___} :> Rest@s] (*{4, 3, 2}, {19, 3, 4}}*)

Syed · Accepted Answer · 2024-02-06 04:34:17Z

data = {{P, 4, 3, 2}, {V, 7, 8, 9, 55}, {P, 19, 3, 4}, {V, 48, 6, 1, 55}}

Using Select:

data // Select[First@# =!= V &] // Map[Rest]

Using Pick:

Rest /@ Pick[data, First@# =!= V & /@ data]

Result:

{{4, 3, 2}, {19, 3, 4}}

4 Answers 4