Selecting Primes from list of list

Question

I want to use Select or Pick for selecting primes in all sublists.

list = {{2, 3, 4, 5, 7}, {8, 9, 11}, {16, 17, 18}}

I can do it by

Table[Select[list[[k]], PrimeQ], {k, 3}]

or

Map[If[PrimeQ[#], #] &] /@ list /. Null -> Sequence[]

resulting in both cases in

{{2, 3, 5, 7}, {11}, {17}}

But I want to use Select or Pick for unknown values of k.

Henrik Schumacher · Accepted Answer · 2019-11-30 13:46:19Z

13

You may try this:

Select[PrimeQ] /@ list

answered Nov 30, 2019 at 13:46

113k7 gold badges197 silver badges339 bronze badges

kglr · Accepted Answer · 2019-11-30 17:35:47Z

12

You can also use Pick with PrimeQ @ list as the selector array:

Pick[#, PrimeQ @ #] & @ list

{{2, 3, 5, 7}, {11}, {17}}

Cases[_?PrimeQ] /@ list

{{2, 3, 5, 7}, {11}, {17}}

answered Nov 30, 2019 at 17:02

403k18 gold badges501 silver badges959 bronze badges

E. Chan-López · Accepted Answer · 2024-02-08 17:36:30Z

list = {{2, 3, 4, 5, 7}, {8, 9, 11}, {16, 17, 18}};

Using Replace at level 2:

Replace[list, n_ /; ! PrimeQ[n] -> Nothing, {2}] (*{{2, 3, 5, 7}, {11}, {17}}*)

eldo · Accepted Answer · 2024-02-08 17:56:16Z

list = {{2, 3, 4, 5, 7}, {8, 9, 11}, {16, 17, 18}};

Using SequenceSplit (new in 11.3)

Join @@ SequenceSplit[#, {_?(Not @* PrimeQ)}] & /@ list

{{2, 3, 5, 7}, {11}, {17}}

Using Position and Delete

p = Position[list, x_ /; ! PrimeQ[x], 2, Heads -> False]

{{1, 3}, {2, 1}, {2, 2}, {3, 1}, {3, 3}}

Delete[p] @ list

{{2, 3, 5, 7}, {11}, {17}}

Syed · Accepted Answer · 2024-02-09 02:22:19Z

Using DeleteCases:

DeleteCases is suitable for nested lists as is maintains list structure while deleting any elements that match the pattern.

list = {{2, 3, 4, 5, 7}, {8, 9, 11}, {16, 17, 18}} DeleteCases[list, _?(Not@*PrimeQ), All]

{{2, 3, 5, 7}, {11}, {17}}

5 Answers 5