As soon as one lets Mathematica use Plus and Times all custom ordering goes out of the window since it always orders the arguments of Plus and Times according to its internal canonical sorting. The functions are inherently Orderless (a Mathematica function attribute which leads to canonical ordering of function arguments). One can not allow the use of Plus for the sum of terms and products of $(\ldots)w$. I modified the code given in the question for polyForm to have a custom StandartForm and TeXForm (using TeXVerbatim of the TeXUtilities package for the latter).

Needs["TeXUtilities`"] (* https://github.com/jkuczm/MathematicaTeXUtilities *) ClearAll[polyForm,polyForm`format] polyForm`format[coeffs_List,var_]:=Row[Row[{If[Head[#[[2]]]===Plus,DisplayForm@RowBox[{"(",#[[2]],")"}],DisplayForm@RowBox[{#[[2]],"\[ThinSpace]"}]],If[#[[1,1]]=!=0,var^#[[1,1]],Nothing]}]&/@coeffs,"+"] polyForm/:Format[polyForm[coeffs_List,var_],TeXForm]:=TeXVerbatim[StringReplace[ToString@TeXForm[polyForm`format[coeffs,var]],{"+-"->"-","\, +"->"+"}]] polyForm/:MakeBoxes[polyForm[coeffs_List,var_],StandardForm]/;BoxForm`UseIcons:=With[ {box=ToBoxes@polyForm`format[coeffs,var]}, InterpretationBox[box,polyForm[coeffs,var]] ] polyForm[poly_,var_]:=polyForm[CoefficientRules[poly,var]//Sort,var]/;(!ListQ[poly]) f = -(w^5/2) + w^4 (1/4 - z/2) + w^3 z + z^4 + w^2 (1 + z^2 + z^3) + w (2 z^2 + z^4) polyForm[f,w]//StandardForm %//TeXForm (*-> z^4+\left(z^4+2 z^2\right)w+\left(z^3+z^2+1\right)w^2+z\, w^3+\left(\frac{1}{4}-\frac{z}{2}\right)w^4-\frac{1}{2}\, w^5*) 

resulting in

which renders in TeX as $$z^4+\left(z^4+2 z^2\right)w+\left(z^3+z^2+1\right)w^2+z\, w^3+\left(\frac{1}{4}-\frac{z}{2}\right)w^4-\frac{1}{2}\, w^5$$

Some of the employed tweaks/replacements for the TeXForm might not be very robust/need to be extended.

Here's my fourth attempt over the last couple of days (three of them were successful and one pissed me off). As others have made steps closer to the solution, I'd get discouraged and set it aside: Eh, it's solved or nearly solved....

Then looking at CoefficientList[poly, {w, z}] or even CoefficientRules[poly, {w, z}], you think, gosh, what to do is obvious, let's try again. But Mathematica's choices about fractions and standard conventions about signs in representing addition and numbers make doing something obvious a bit of a pain. @CarlWoll gets close [it] in an elegant way (fractions not in front but otherwise brilliant--now there's a fractions-in-front option); @MauriciodeOliveira gets the formatting perfect, but it doesn't seem elegant to me. Just to be clear, I don't think my solution is all that elegant, either. However, whereas @MauriciodeOliveira aims at the right TeXForm, mine gets the right box form that produces the right TeXForm. The box form has some minor advantages, such as you can copy and paste it as input; or as @CarlWoll suggests in a comment, the code can be packaged into a wrapper that both formats output and works with TeXForm. It's because of this distinction I feel this method adds something to the other answers, and therefore it is worth sharing.

As for elegance, because it's the fourth attempt, it is about half as long as it used to be. :) But you still have to do something about the coefficient 1, sums with one term, and - as a unary/binary op. Luckily, CoefficientRules takes care of all the zero coefficients/terms.

(* helper functions *) ClearAll[cRules, toPowerBoxes, parenthesizeRow, coeffToBoxes, toMonomialBoxes]; cRules[t_][poly_] := Association@Sort@CoefficientRules[poly, {t}]; toPowerBoxes[t_] := KeyMap[MakeBoxes[#] &[t^#] &@*First]; parenthesizeRow[boxes : {b : Except[_List]}] := RowBox[{"(", b, ")"}]; parenthesizeRow[boxes_] := RowBox[{"(", RowBox@Flatten@boxes, ")"}]; (* first coeff is treated different *) coeffToBoxes[assoc_] := MapAt[MakeBoxes, 1]@ MapAt[{If[Negative[#], "-", "+"], MakeBoxes[#] &@Abs@#} &, 2 ;;]@ assoc; (* ±1 are specials cases; no zero coeffs *) toMonomialBoxes["1", coeff_] := coeff; toMonomialBoxes[power_, {sign_, coeff_}] := {sign, RowBox[{coeff," ",power}]}; toMonomialBoxes[power_, "1"] := power; toMonomialBoxes[power_, RowBox[{"-", "1"}]] := RowBox[{"-", power}]; toMonomialBoxes[power_, coeff_] := RowBox[{coeff, " ", power}]; 

Example:

RawBoxes@ RowBox@ Riffle[#, "+"] &@ KeyValueMap[toMonomialBoxes]@ Map[parenthesizeRow]@ Map[ KeyValueMap[toMonomialBoxes]@* coeffToBoxes@* toPowerBoxes[z]@* cRules[z] ]@ toPowerBoxes[w]@cRules[w][poly] % // TeXForm 

$\displaystyle \left(\frac{7}{3} z^{25}\right)+\left(-z^{21}\right) w^4+\left(-\frac{1}{4} z\right) w^5+\left(-\frac{8}{5} z^{39}\right) w^6+\left(-\frac{5}{4}-\frac{5}{4} z^{33}\right) w^8+\left(3 z^4-2 z^{27}\right) w^{13}+\left(-\frac{6}{5} z^3+\frac{1}{5} z^{27}\right) w^{20}+\left(-\frac{4}{3} z^{36}\right) w^{22}+\left(z^{17}\right) w^{23}+(-1) w^{24}+\left(\frac{1}{2} z^2\right) w^{25}+\left(z^{26}-\frac{1}{5} z^{33}\right) w^{26}+\left(-\frac{1}{3} z^{11}\right) w^{28}+\left(\frac{5}{3} z^{16}-\frac{2}{5} z^{37}\right) w^{29}+\left(-\frac{6}{5} z^{17}\right) w^{32}+\left(-2 z^{27}\right) w^{33}+\left(-5 z^{17}-4 z^{28}\right) w^{38}+\left(\frac{7}{5} z^{18}\right) w^{39}+\left(-z^{12}\right) w^{40}$

Dataset approach:

ds = Dataset@ Map[toPowerBoxes[z]@*cRules[z]]@ toPowerBoxes[w]@cRules[w][poly]; ds[All, coeffToBoxes /* KeyValueMap[toMonomialBoxes] /* parenthesizeRow][ KeyValueMap[toMonomialBoxes] ] // Normal // Riffle[#, "+"] & // RowBox // RawBoxes 

or

plusBox[b_] := RowBox@Riffle[b, "+"]; ds[Map[coeffToBoxes /* KeyValueMap[toMonomialBoxes] /* parenthesizeRow ] /* KeyValueMap[toMonomialBoxes] /* plusBox ] // RawBoxes 

Original Answer

Since you are not asking for efficiency, I find it more productive to deconstruct the polynomial and use HoldForm instead of boxes to handle the ordering. From there, the standard TeXForm does the job well. The tricky part is to hold the Plus inside the HoldForm. Another aspect that I find important is the handling of negative signs inside parenthesis, as one would not like to have y + y x - x print as y + (-1 + y) x but rather as y - (1 - y) x.

The code needs three auxiliary functions: GetSign, to obtain the sign of an expression, HoldTerms, to perform the multiplication of two terms holding its ordering and hiding possible 1s, and PolyForm, which does the bulk of the job by reconstructing the polynomial using HoldForm to preserve the desired ordering. Here they are:

GetSign[a_?NumberQ] := If[a < 0, -1, 1]; GetSign[a_Times | a_Plus] := GetSign[a[[1]]]; GetSign[a_] = 1; HoldTerms[coeff_, mon_] := If[coeff === 1, mon, If[mon === 1, coeff, HoldForm[Times[coeff, mon]]]]; PolyForm[p_, x_Symbol, formatCoefficient_ : Identity] := Module[ {coeff, sign, mon}, (* get polynomial coefficients *) coeff = CoefficientList[Collect[p, x], x]; (* calculate corresponding monomial and remove zero coefficients *) {coeff, mon} = Transpose[ DeleteCases[ Transpose[{coeff, Table[x^i, {i, 0, Length[coeff] - 1}]}], _?(PossibleZeroQ[#[[1]]] &)] ]; (* factor sign of coefficients out *) sign = GetSign /@ coeff; coeff *= sign; (* format coefficients *) coeff = formatCoefficient /@ coeff; (* multiply by monomials and hold, then multiply by sign *) coeff = sign*MapThread[HoldTerms, {coeff, mon}]; (* return *) Return[If[ Length[coeff] > 1, (* Apply Plus inside hold and return *) With[{z = coeff}, HoldForm[z]] /. List -> Plus, (* first entry if list of one *) coeff[[1]] ]]; ]; 

From these, PolyToTeX basically applies TeXForm to the result of PolyForm. In the case of multiple variables it uses PolyForm to format the coefficients first. This can be extended to more than 2 variables if wanted.

PolyToTeX[p_, x_Symbol] := TeXForm[PolyForm[p, x]]; PolyToTeX[p_, x_Symbol, y_Symbol] := TeXForm[PolyForm[p, x, PolyForm[#, y] &]]; 

Some examples.

PolyToTeX[y + y x - x, x] (* factors negative sign *) 

y-(1-y) x

PolyToTeX[y + y x - x, y] (* keeps ordering in the sum *) 

-x+(1+x) y

PolyToTeX[y + y x/2 - x, x] (* uses \frac and factor negative sign *) 

y-\left(1-\frac{y}{2}\right) x

or

$y-\left(1-\frac{y}{2}\right) x$

PolyToTeX[y + y^2 z x - x + y x - y^2 x, x, y] (* format coefficients as poly in y *) 

y-\left(1-y+(1-z) y^2\right) x

or

$y-\left(1-y+(1-z) y^2\right) x$

p = (w^5/2) + w^4 (-1/4 + z/2) + w^3 z + z^4 + w^2 (1 + z^2 + z^3) + w (2 z^2 + z^4); PolyToTeX[p, w] (* the test polynomial with a flipped minus sign *) 

z^4+\left(2 z^2+z^4\right) w+\left(1+z^2+z^3\right) w^2+z w^3-\left(\frac{1}{4}-\frac{z}{2}\right) w^4+\frac{w^5}{2}

or

$z^4+\left(2 z^2+z^4\right) w+\left(1+z^2+z^3\right) w^2+z w^3-\left(\frac{1}{4}-\frac{z}{2}\right) w^4+\frac{w^5}{2}$

Look at

InputForm[PolyForm[p, w]] 

to see how PolyForm works

HoldForm[z^4 + HoldForm[(2*z^2 + z^4)*w] + HoldForm[(1 + z^2 + z^3)w^2] + HoldForm[zw^3] - HoldForm[(1/4 - z/2)*w^4] + HoldForm[w^5/2]]

Modified Answer

The requirements added on the comments change the code significantly, hence a new section. The main difficulty is that the rules for the formatting the coefficients are different than the rules for formatting the polynomial, which requires handling different options in each case. Moreover, the requirement for forcing parentheses is also not handled natively by TeXForm, but is handled nicely by the package TexUtilities, which is now a dependence.

Needs["TeXUtilities`"] (* https://github.com/jkuczm/MathematicaTeXUtilities *) 

The updated auxiliary functions are:

GetSign[a_?NumberQ] := If[a < 0, -1, 1]; GetSign[a_Times | a_Plus] := GetSign[a[[1]]]; GetSign[a_] = 1; HoldTerms[1, mon_, sign_ : 1] := sign*mon; HoldTerms[coeff_, 1, sign_ : 1] := sign*coeff; HoldTerms[coeff_Rational, mon_, sign_ : 1] := sign*HoldForm[Times[HoldForm[coeff], mon]]; HoldTerms[coeff_, mon_, sign_ : 1] := Times[sign, HoldForm[Times[coeff, mon]]]; Format[ParenthesizeTeX[x__], TeXForm] := TeXDelimited["\\left(", x, "\\right)", "DelimSeparator" -> ""]; ParenthesizeTeXOptional[ a_Plus | a_Symbol | a : (Power[_, _Integer]) | a_?(NumberQ[#] && Positive[#] &)] := a; ParenthesizeTeXOptional[a_] := ParenthesizeTeX[a]; Options[PolyForm] = { FactorSign -> False, ParenthesizeAll -> True, FormatCoefficient -> Identity }; PolyForm[p_, x_Symbol, opts : OptionsPattern[PolyForm]] := Module[ {coeff, sign, mon}, (* get polynomial coefficients *) coeff = CoefficientList[Collect[p, x], x]; (* calculate corresponding monomial and remove zero coefficients *) {coeff, mon} = Transpose[ DeleteCases[ Transpose[{coeff, Table[x^i, {i, 0, Length[coeff] - 1}]}], _?(PossibleZeroQ[#[[1]]] &)]]; (* factor sign of coefficients out *) If[OptionValue[FactorSign] === True, sign = GetSign /@ coeff; coeff *= sign; ]; (* format coefficients *) coeff = OptionValue[FormatCoefficient] /@ coeff; (* wrap all terms in parenthesis *) coeff = If[OptionValue[ParenthesizeAll], ParenthesizeTeX /@ coeff , ParenthesizeTeXOptional /@ coeff ]; (* multiply by monomials and hold *) coeff = If[OptionValue[FactorSign] === True, (* first term might still factor *) Prepend[MapThread[HoldTerms, Rest /@ {coeff, mon, sign}], HoldTerms[sign[[1]]*coeff[[1]], mon[[1]]]] , MapThread[HoldTerms, {coeff, mon}] ]; Return[If[Length[coeff] > 1, (* Apply Plus inside hold and return *) With[{z = coeff}, HoldForm[z]] /. List -> Plus , (* first entry if list of one *) coeff[[1]]] ]; ]; PolyForm[p_, {x_Symbol}, opts : OptionsPattern[PolyForm]] := PolyForm[p, x, opts]; PolyForm[p_, {x_Symbol, y__Symbol}, opts : OptionsPattern[PolyForm]] := PolyForm[p, x, FormatCoefficient -> (PolyForm[#, {y}, FactorSign -> True, ParenthesizeAll -> False, opts] &), opts]; 

The drivers are also different in order to interfere with the options.

PolyToTeX[p_, x_Symbol, opts___ : OptionsPattern[PolyForm]] := TeXForm[PolyForm[p, x, opts]]; PolyToTeX[p_, {x__Symbol}, opts___ : OptionsPattern[PolyForm]] := TeXForm[PolyForm[p, {x}, opts]]; 

For the first example in the comments:

p = (-1/2 + 3 z + 4/5 z^3) + (-3/5 z^4) w^3 + 1/5 w^4; PolyToTeX[p, {w, z}] 

produce

\left(-\frac{1}{2}+3 z+\frac{4}{5} z^3\right)+\left(-\frac{3}{5} z^4\right) w^3+\left(\frac{1}{5}\right) w^4

or

$\left(-\frac{1}{2}+3 z+\frac{4}{5} z^3\right)+\left(-\frac{3}{5} z^4\right) w^3+\left(\frac{1}{5}\right) w^4$

For the second example in the comments:

p = 1 + (1 - z + 3/5 z^4 + z^5) w - w^2 - z^3 w^5 + (-2/3 z^3 + z^5) w^6 PolyToTeX[p, {w, z}] 

produce

\left(1\right)+\left(1-z+\frac{3}{5} z^4+z^5\right) w+\left(-1\right) w^2+\left(-z^3\right) w^5+\left(-\frac{2}{3} z^3+z^5\right) w^6

or

$\left(1\right)+\left(1-z+\frac{3}{5} z^4+z^5\right) w+\left(-1\right) w^2+\left(-z^3\right) w^5+\left(-\frac{2}{3} z^3+z^5\right) w^6$

One can also use options to obtain other formats. For example:

PolyToTeX[p, {w, z}, FactorSign->True, ParenthesizeAll->False] 

produces

1+\left(1-z+\frac{3}{5} z^4+z^5\right) w-w^2-z^3 w^5-\left(\frac{2}{3} z^3-z^5\right) w^6

or

$1+\left(1-z+\frac{3}{5} z^4+z^5\right) w-w^2-z^3 w^5-\left(\frac{2}{3} z^3-z^5\right) w^6$

which is similar to the format of the original answer.

The new code should also works for more than two variables, as in:

p = (-1/2 + (x^2 + 1/2) 3 z + x 4/5 z^3) + (-3/5 z^4 - x) w^3 + 1/5 w^4; PolyToTeX[p, {w, z, x}] 

which produces

\left(-\frac{1}{2}+\left(\frac{3}{2}+3 x^2\right) z+\left(\frac{4}{5} x\right) z^3\right)+\left(-x-\frac{3}{5} z^4\right) w^3+\left(\frac{1}{5}\right) w^4

or

$\left(-\frac{1}{2}+\left(\frac{3}{2}+3 x^2\right) z+\left(\frac{4}{5} x\right) z^3\right)+\left(-x-\frac{3}{5} z^4\right) w^3+\left(\frac{1}{5}\right) w^4$

I haven't tested it enough though.