9
$\begingroup$

I have the following formula

expr = 2 ArcCsc[r] + 7 ArcTan[Sqrt[-1 + r^2]] + 10 ArcTan[r - Sqrt[-1 + r^2]]

I have seen plotting it or also assigning different numerical values that it is constant and equal to this number 10.9956.

How can I simplify this expression in order to obtain a precise constant value. I have tried with TrigExpand, TrigReduced, FunctionExpand, but I was not successful.

Improve this question
$\endgroup$
10
  • $\begingroup$ Looks like (7*Pi)/2 for r>0 but I also could not make Mathematica show this on its own. $\endgroup$ Commented Feb 21 at 13:33
  • $\begingroup$ I have tried FullSimplify, but I was not able to simplify it. How did you manage to obtain such a result? Thanks you very much $\endgroup$ Commented Feb 21 at 13:35
  • 1
    $\begingroup$ Oh, I simply did expr/.r->1 and Mathematica gave back (7*Pi)/2, and from the plot it is clear that is same value for all r>0 $\endgroup$ Commented Feb 21 at 13:37
  • 1
    $\begingroup$ @Domen Very interesting. I haven't updated. Maybe in the new version the following works: FullSimplify[expr /. r -> 1/Sin[a], Assumptions -> 0 < a< Pi/2] ? In MA14.1 it almost reaches the desired answer. $\endgroup$ Commented Feb 21 at 16:06
  • 2
    $\begingroup$ It's not too hard to show (by drawing a right triangle with legs $1$ and $\sqrt{r^2 -1}$ and hypotenuse $r$) that $\csc^{-1}(r) + \tan^{-1}(\sqrt{r^2 - 1}) = \pi/2$ for $r > 0$. I suspect there are ways to apply the arctangent addition formula to simplify it further. $\endgroup$ Commented Feb 21 at 22:33

7 Answers 7

Reset to default
8
$\begingroup$

The expression is so peculiar, that it surely did not appear accidental. Therefore it's often simpler to start in reverse:

f[r] = 2 ArcCsc[r] + 7 ArcTan[Sqrt[-1 + r^2]] + 10 ArcTan[r - Sqrt[-1 + r^2]]; Simplify[D[#, r] & /@ List @@ f[r], r > 0]

$$ \left\{-\frac{2}{r \sqrt{r^2-1}},\frac{7}{r \sqrt{r^2-1}},-\frac{5}{r \sqrt{r^2-1}}\right\} $$

As all expression have the same derivative, it's already a smoking gun that someone just obfuscated the expression.

Integrate[1/(r Sqrt[-1 + r^2]), r]

$$\tan ^{-1}\left(\sqrt{r^2-1}\right)$$

The idea is now to bring everything into a $\tan^{-1}$ expression.

With a bit of help of wikipedia and some identities:

Simplify[f[r] /. (ArcCsc[r] -> \[Pi]/2 - ArcTan[Sqrt[r^2 - 1]]), r > 0] \[Pi] + 5 ArcTan[Sqrt[-1 + r^2]] + 10 ArcTan[r - Sqrt[-1 + r^2]]

And more identities:

5 ArcTan[Sqrt[-1 + r^2]] /. ArcTan[x_] :> 2 ArcTan[x/(1 + Sqrt[1 + x^2])] 10 ArcTan[Sqrt[-1 + r^2]/(1 + Sqrt[r^2])]

Did I say identities?

u = Sqrt[-1 + r^2]/(1 + Sqrt[r^2]); v = r - Sqrt[-1 + r^2]; FullSimplify[ArcTan[(u + v)/(1 - u v)], r > 0] \[Pi]/4

This expression Mathematica was actually able to simplify.

So we obtain: $\pi + 10 \frac{\pi}{4} = \frac{7\pi}{2}$, as ordered.

Improve this answer
$\endgroup$
7
$\begingroup$

If you plot it, you can see that it is constant only for positive $r$:

Plot[expr, {r, -3, 3}]

enter image description here

One way to obtain the simplification is to expand it around $r=0$ using Series:

FullSimplify[Series[expr, {r, 0, 10}], r > 0] (* 7 π/2 + O[r]^11 *)

The value of your expression for $r>0$ is therefore $7\pi/2$.

To be sure that the value is constant, we can simply differentiate it, and see that the derivative is indeed zero:

FullSimplify[D[expr, r], r > 0] (* 0 *)
Improve this answer
$\endgroup$
6
$\begingroup$

As a general technique to handling expressions of this sort, computing the sine and cosine often allows simplification.

expr = 2 ArcCsc[r] + 7 ArcTan[Sqrt[-1 + r^2]] + 10 ArcTan[r - Sqrt[-1 + r^2]]; Assuming[r > 0, FullSimplify[Sin[expr]]] (* -1 *) Assuming[r > 0, FullSimplify[Cos[expr]]] (* 0 *)
Improve this answer
$\endgroup$
2
  • $\begingroup$ But how can one retrieve the original value of $7\pi/2$ out of this? $\endgroup$ Commented Feb 21 at 16:56
  • $\begingroup$ @Domen I was suggesting this as a general approach that can be helpful with this type of problem, rather than a complete solution. Clearly, there remains a mod 2 pi uncertainty, but this can be resolved numerically. $\endgroup$ Commented Feb 21 at 17:08
6
$\begingroup$ 
$Version (* "14.2.0 for Mac OS X ARM (64-bit) (December 26, 2024)" *) expr = 2 ArcCsc[r] + 7 ArcTan[Sqrt[-1 + r^2]] + 10 ArcTan[r - Sqrt[-1 + r^2]]; expr /. {{r -> 1}, {r -> 2}}

enter image description here

((expr /. (List /@ Thread[r -> Range[10]]))/Pi // RootApproximant)*Pi

enter image description here

Improve this answer
$\endgroup$
5
$\begingroup$

From the Fundamental Theorem of Calculus:

$$f(r) = f(c) + \int_c^r f'(R) \; dR \,.$$

For r > 0:

(expr /. r -> 1) + Integrate[D[expr, r], {r, 1, r}, Assumptions -> r > 0] (* (7 \[Pi])/2 *)

For the rest of the real domain:

(expr /. r -> -1) + Integrate[Simplify[#, r < 0] & /@ Simplify[D[expr, r]], {r, -1, r}, Assumptions -> r < -1] // Simplify[#, r < -1] & (* -((7 \[Pi])/2) + 4 ArcTan[Sqrt[-1 + r^2]] *)
Improve this answer
$\endgroup$
2
$\begingroup$

The desired simplification is currently (version 14.1) beyond the MA capabilities.

I came to this conclusion after trying several possibilities and seeing workarounds in other posts. It is better to know that something is impossible rather than wasting hours to coerce MA to do certain transformations.

Improve this answer
$\endgroup$
1
$\begingroup$

The standard method to treat trigonometric and inverse trigonometric algebra is TrigToExp and Simplify expressions of Log with identical factors or Exp with identical arguments.

 exprs[r_] := 2 ArcCsc[r] + 7 ArcTan[Sqrt[-1 + r^2]] + 10 ArcTan[r - Sqrt[-1 + r^2]] expr // TrigToExp

$$-2 i \log \left(\sqrt{1-\frac{1}{r^2}}+\frac{i}{r}\right)-5 i \log \left(1+i \left(r-\sqrt{r^2-1}\right)\right)+5 i \log \left(1-i \left(r-\sqrt{r^2-1}\right)\right)-\frac{7}{2} i \log \left(1+i \sqrt{r^2-1}\right)+\frac{7}{2} i \log \left(1-i \sqrt{r^2-1}\right)$$

 bxprs[r_] = I ((-I expr // TrigToExp) //. {a_ Log[x_] + b_ Log[y_] /; (a + b == 0) :> a Log[x/y]})

$$i \ \left(-2 \log \left(\sqrt{1-\frac{1}{r^2}}+\frac{i}{r}\right)+5 \ \log \left(\frac{1-i \left(r-\sqrt{r^2-1}\right)}{1+i \left(r-\sqrt{r^2-1}\right)}\right)+\frac{7}{2} \ \log \left(\frac{1-i \sqrt{r^2-1}}{1+i \sqrt{r^2-1}}\right)\right)$$

For all algebraic transformations of expressions with branch cuts, the result has to be confirmed graphically

Plot[Evaluate[{ReIm[exprs[r]], ReIm[bxprs[r]]}], {r, -2, 2}, PlotLegends -> {"Re 1", "Im 1", "Re 2", "Im 2"}, Exclusions -> "Discontinuities", Ticks -> {Automatic, Range[-4 \[Pi], 6 \[Pi], 2 \[Pi]]}, PlotStyle -> {{Blue, Thickness[0.02]}, {Red,Thickness[0.02]}, {Black}, {White}}]

inverse trigs vs logs

Improve this answer
$\endgroup$
2
  • 1
    $\begingroup$ So where is the result $7\pi/2$? $\endgroup$ Commented Feb 23 at 21:17
  • $\begingroup$ Apparently expr is not constant, But expr[1]=7 Pi/2 and expr'[r]=0. $\endgroup$ Commented Feb 23 at 23:16

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.